bat怎么安装mysql

在Windows10系统下，使用bat一键安装MySQL非常方便，下面就来分享一下如何操作。

首先，我们需要下载MySQL的压缩包，下载地址：https://cdn.mysql.com//Downloads/MySQL-8.0/mysql-8.0.22-winx64.zip，下载完毕后解压到本地。解压后的目录结构如下：

接下来，我们需要新建一个bat文件，并把以下内容复制进去，然后将这个文件放到MySQL解压后的目录里，并以右键管理员的方式运行：

@setlocal enabledelayedexpansion
@echo off
color f0

rem 编程技术www.vcvb.cn出品，转载请保留此信息。
title MYSQL一键安装

set basedir=%~dp0
set bin=%~dp0\bin

cd /d %~dp0

if exist !bin!\mysqld.exe (
rem 写入配置文件>my.ini
echo [mysqld]>>my.ini
echo port=3306>>my.ini
echo basedir=!basedir!>>my.ini
echo datadir=!basedir!\Data>>my.ini
echo log-error=!basedir!\Logs.log>>my.ini
echo max_connections=200>>my.ini
echo max_connect_errors=10>>my.ini
echo character-set-server=utf8mb4>>my.ini
echo default-storage-engine=INNODB>>my.ini
echo default_authentication_plugin=mysql_native_password>>my.ini
echo local_infile=ON>>my.ini
echo.>>my.ini

echo [mysql]>>my.ini
echo default-character-set=utf8mb4>>my.ini
echo local_infile=ON>>my.ini
echo.>>my.ini

echo [client]>>my.ini
echo port=3306>>my.ini
echo default-character-set=utf8mb4>>my.ini

rem 添加环境变量
echo 开始检查环境变量...
for /f "tokens=2*" %%i in ('reg query "HKLM\SYSTEM\ControlSet001\Control\Session Manager\Environment" /v Path ^| findstr /i "path"') do (set "p=%%j")
for /f "tokens=*" %%a in ('echo !p! ^| find /i "!bin!"') do (set flag=1)
if not defined flag (
echo 开始添加环境变量
setx Path "!p!;!bin!" /M | find "成功" && echo 环境变量添加成功
set p=!Path!
) else (
echo 环境变量已存在，无需设置。
)
echo.

rem 初始化 --console
cd !bin!
echo --------初始化数据库开始--------
echo 开始初始化数据库
mysqld --initialize-insecure >> !basedir!\Logs.log
echo --------初始化数据库结束--------

rem 安装服务
echo 开始安装服务
mysqld --install MySQL | find "successfully" && echo 服务安装成功
echo.

rem 启动服务
echo 开始启动MySQL服务
net start MySQL
echo.

mysql -u root -e "ALTER USER 'root'@'localhost' IDENTIFIED WITH mysql_native_password BY '1qaz';"

echo 安装完成
) else (
echo 请将本工具放在解压后的MySQL根目录下再打开
)
pause >nul

运行后，会自动根据你配置的环境变量，进行MySQL的安装和配置。

安装完成后，记得保存MySQL的密码，其默认密码为：1qaz。登录MySQL的命令为：mysql -u root -p，输入密码后即可登录。

需要注意的是，如果在重新安装MySQL的时候，需要先删除data目录下的数据。

总的来说，使用bat一键安装MySQL还是非常方便的，可以让我们快速地安装和配置MySQL。

扫码添加UTHEME微信为好友

· 分享WordPress相关技术文章，主题上新与优惠动态早知道。
· 微信端最大WordPress社群，限时免费入群。